ugui/lib/ugui.c3l/src/ugui_button.c3

module ugui;

import std::io;

// button element
struct ElemButton {
	int filler;
}


macro Ctx.button(&ctx, String label = "", String icon = "", ...)
	=> ctx.button_id(@compute_id($vasplat), label, icon);
fn ElemEvents? Ctx.button_id(&ctx, Id id, String label, String icon)
{
	id = ctx.gen_id(id)!;
	Elem *parent = ctx.get_parent()!;
	Elem *elem = ctx.get_elem(id, ETYPE_BUTTON)!;
	Style* style = ctx.styles.get_style(@str_hash("button"));
	
	Sprite* sprite = icon != "" ? ctx.sprite_atlas.get(icon)! : &&(Sprite){};

	Rect min_size = {0, 0, style.size, style.size};
	Rect text_size = ctx.get_text_bounds(label)!;
	Rect icon_size = sprite.rect();

	ushort h_lh = (ushort)(ctx.font.line_height() / 2);
	ushort left_pad = label != "" ? h_lh : 0;
	ushort inner_pad = label != "" && icon != "" ? h_lh : 0;
	ushort right_pad = left_pad;
	
	/*    |left_pad
	 * +--v-----------------------------------+
	 * |<->+--------+                         |
	 * |   |        |   +-----------------+   |
	 * |   |  icon  |   |     label       |   |
	 * |   |        |   +-----------------+   |
	 * |   +--------+<->|                 |<->|
	 * +-------------^--------------------^---+
	 *               |inner_pad           |right_pad
	 */
	
	Rect tot_size = {
		.w = (short)max(min_size.w, icon_size.w + text_size.w + left_pad + inner_pad + right_pad),
		.h = (short)max(min_size.h, max(icon_size.h, text_size.h)),
	};
	
	elem.bounds = ctx.layout_element(parent, tot_size, style);
	if (elem.bounds.is_null()) return {};
	elem.events = ctx.get_elem_events(elem);
	Rect content_bounds = elem.content_bounds(style);
	
	Rect text_bounds = {
		.x = content_bounds.x + icon_size.w + left_pad + inner_pad,
		.y = content_bounds.y,
		.w = content_bounds.w - icon_size.w - left_pad - inner_pad - right_pad,
		.h = content_bounds.h
	};
	text_bounds = text_size.center_to(text_bounds);
	
	Rect icon_bounds = {
		.x = content_bounds.x,
		.y = content_bounds.y,
		.w = icon_size.w + right_pad + inner_pad,
		.h = (short)max(icon_size.h, content_bounds.h)
	};
	icon_bounds = icon_size.center_to(icon_bounds);

	bool is_active = ctx.elem_focus(elem) || elem.events.mouse_hover;
	Style s = *style;
	if (is_active) {
		s.secondary = s.primary;
		s.bg = s.accent;
	}

	ctx.push_rect(elem.bounds, parent.div.z_index, &s)!;
	if (icon != "") {
		ctx.push_sprite(icon_bounds, sprite.uv(), ctx.sprite_atlas.id, parent.div.z_index, type: sprite.type)!;
	}
	if (label != "") {
		ctx.push_string(text_bounds, label, parent.div.z_index, style.fg)!;
	}
	return elem.events;
}


// FIXME: this should be inside the style
macro Ctx.checkbox(&ctx, String desc, Point off, bool* active, String tick_sprite = {}, ...)
	=> ctx.checkbox_id(@compute_id($vasplat), desc, off, active, tick_sprite);
fn void? Ctx.checkbox_id(&ctx, Id id, String description, Point off, bool* active, String tick_sprite)
{
	id = ctx.gen_id(id)!;

	Elem *parent = ctx.get_parent()!;
	Elem *elem = ctx.get_elem(id, ETYPE_BUTTON)!;
	Style* style = ctx.styles.get_style(@str_hash("checkbox"));

	Rect size = {off.x, off.y, style.size, style.size};
	elem.bounds = ctx.layout_element(parent, size, style);

	// if the bounds are null the element is outside the div view,
	//  no interaction should occur so just return
	if (elem.bounds.is_null()) return;

	elem.events = ctx.get_elem_events(elem);
	if (elem.events.mouse_hover && elem.events.mouse_release) *active = !(*active);
	
	if (tick_sprite != {}) {
		ctx.push_rect(elem.bounds, parent.div.z_index, style)!;
		if (*active) {
			ctx.draw_sprite_raw(tick_sprite, elem.bounds, center: true)!;
		}
	} else {
		ctx.push_rect(elem.bounds, parent.div.z_index, style)!;
		if (*active) {
			ushort x = style.size / 4;
			Rect check = elem.bounds.add({x, x, -x*2, -x*2});
			Style s = *style;
			s.bg = s.primary;
			s.margin = s.border = s.padding = {};
			ctx.push_rect(check, parent.div.z_index, &s)!;
		}
	}
}

// FIXME: this should be inside the style
macro Ctx.toggle(&ctx, String desc, Point off, bool* active)
	=> ctx.toggle_id(@compute_id($vasplat), desc, off, active);
fn void? Ctx.toggle_id(&ctx, Id id, String description, Point off, bool* active)
{
	id = ctx.gen_id(id)!;

	Elem *parent = ctx.get_parent()!;
	Elem *elem = ctx.get_elem(id, ETYPE_BUTTON)!;
	Style* style = ctx.styles.get_style(@str_hash("toggle"));

	Rect size = {off.x, off.y, style.size*2, style.size};
	elem.bounds = ctx.layout_element(parent, size, style);

	// if the bounds are null the element is outside the div view,
	//  no interaction should occur so just return
	if (elem.bounds.is_null()) return;

	elem.events = ctx.get_elem_events(elem);
	if (elem.events.mouse_hover && elem.events.mouse_release) *active = !(*active);

	// Draw the button
	// FIXME: THIS IS SHIT
	ctx.push_rect(elem.bounds, parent.div.z_index, style)!;
	Rect t = elem.bounds.add({*active ? (style.size+3) : +3, +3, -style.size-6, -6});
	Style s = *style;
	s.bg = s.primary;
	s.margin = s.border = s.padding = {};
	ctx.push_rect(t, parent.div.z_index, &s)!;
}